Описание
Возвращает закладку, указывающую запись, которая была добавлена или изменена последней.

Значение
Возвращаемое значение является массивом типа Variant элементов типа Byte.

Замечания
Свойство LastModified позволяет найти последнюю измененную или добавленную запись. Данное свойство используется с табличными и динамическими объектами Recordset. Чтобы свойство LastModified имело значение, запись должна быть изменена в самом объекте Recordset.

Пример
Следующая программа использует свойство LastModified для перевода указателя текущей записи на измененную запись или на новую запись.

Sub LastModifiedX()

	Dim dbsNorthwind As Database
	Dim rstEmployees As Recordset
	Dim strFirst As String
	Dim strLast As String

	Set dbsNorthwind = OpenDatabase("Борей.mdb")
	Set rstEmployees = dbsNorthwind.OpenRecordset("Сотрудники", dbOpenDynaset)
	With rstEmployees
		' Сохраняет текущие данные.
		strFirst = !Имя
		strLast = !Фамилия
		' Изменяет данные в текущей записи.
		.Edit
		!Имя = "Иван"
		!Фамилия = "Иванов"
		.Update
		' Переводит указатель текущей записи на последнюю 
		' измененную или добавленную запись.
		.Bookmark = .LastModified
		Debug.Print "Последние измененные данные после вызова Edit: " &  !Имя & " " & !Фамилия
		' Восстанавливает исходные данные, 
		' измененные только для демонстрации.
		.Edit
		!Имя = strFirst
		!Фамилия = strLast
		.Update
		' Добавляет новую запись.
		.AddNew
		!Имя = "Петр"
		!Фамилия = "Петров"
		.Update
		' Переводит указатель текущей записи на последнюю 
		' измененную или добавленную запись.
		.Bookmark = .LastModified
		Debug.Print "Последние измененные данные после вызова AddNew: " & !Имя & " " & !Фамилия
		' Удаляет новую запись, созданную только для демонстрации.
		.Delete
		.Close
	End With
	dbsNorthwind.Close
End Sub